10 TRAP1000:IFL=1ANDNC=0THENGETKEYK$:IFK$<>"M"THEN10
12 IFNC=1THEN770
15 IFL=0THEN20:ELSE50
20 C0=1:L0=0:C1=6:L6=5:C1$=CHR$(34):R$=CHR$(18):O$=CHR$(146)
30 COLOR0,1,0:COLOR1,8,5:COLOR4,1,0:GRAPHIC1,1
40 GOSUB50
50 GRAPHIC0,1:PRINTTAB(17)"MAIN MENU":FORI=0TO8:PRINTTAB(I+17)CHR$(163);:NEXT:PRINT:
60 PRINT" 1. SET BACKGROUND COLOR":PRINT:
70 PRINT" 2. SET BACKGROUND LUMANANCE":PRINT
80 PRINT" 3. SET FORGROUND COLOR":PRINT
90 PRINT" 4. SET FORGROUND LUMANANCE":PRINT:
100 PRINT" 5. ENTER DRAW MODE (CLEARED SCREEN)":PRINT:
110 PRINT" 6. RETURN TO DRAW MODE":PRINT:
120 PRINT" 7. SAVE WORK TO DISC (HI-RES=32 BLKS)":PRINT:
130 PRINT" 8. LOAD HI-RES SCREEN FROM DISK":PRINT:
140 PRINT" 9. ***** INSTRUCTIONS *****":PRINT:
150 PRINT" 0. QUIT":PRINT
160 PRINT" ENTER ABOVE CHOISE "
170 GETK$:IFK$=""THEN170
180 IFK$="1"THENGOSUB290
190 IFK$="2"THENGOSUB320
200 IFK$="3"THENGOSUB350:GOTO50
210 IFK$="4"THENGOSUB380:GOTO50
220 IFK$="5"THENGRAPHIC1,1:GOTO770:REM * ENTER DRAW MODE (SCNCLR)
230 IFK$="6"THENGOSUB1010:GRAPHIC1:GOTO780:REM * RETURN TO DRAW MODE (NO CLR)
240 IFK$="7"THENGRAPHIC0,1:PRINT:PRINT:GOSUB410
250 IFK$="8"THENGRAPHIC0,1:PRINT:PRINT:GOTO480
260 IFK$="9"THENGOSUB550
270 IFK$="0"THENGOSUB660
280 GOTO170
290 C0=C0+1:IFC0=17THENC0=1
300 COLOR0,C0,L0:COLOR4,C0,L0
310 RETURN
320 L0=L0+1:IFL0=8THENL0=0
330 COLOR0,C0,L0:COLOR4,C0,L0
340 RETURN
350 C1=C1+1:IFC1=17THENC1=1
360 COLOR1,C1,L1
370 RETURN
380 L1=L1+1:IFL1=8THENL1=0
390 COLOR1,C1,L1
400 RETURN
410 PRINT" 1. SAVE SCREEN":PRINT
420 PRINT" 2. RETURN TO MAIN MENU":PRINT:
430 PRINT" ENTER CHOISE"
440 GETK$:IFK$=""THEN440
450 IFK$="1"THEN870
460 IFK$="2"THEN50
470 GOTO440
480 PRINT" 1. LOAD SCREEN":PRINT
490 PRINT" 2. RETURN TO MAIN MENU":PRINT:
500 PRINT" ENTER CHOISE"
510 GETK$:IFK$=""THEN510
520 IFK$="1"THEN920
530 IFK$="2"THEN50
540 GOTO510
550 GRAPHIC0,1:PRINTTAB(14)"INSTRUCTIONS":FORI=0TO11:PRINTTAB(I+14)CHR$(163);:NEXT
560 PRINT:
570 PRINT"  WHEN RUNNING THE DRAW & FILE PROGRAM  YOU WILL BE GIVEN THE MAIN MENU."
580 PRINT"  MAKE YOUR SELECTOIN FROM THIS MENU BY ENTERING THE NUMBER OF THE ";
590 PRINT"SELECTION.":PRINT"  WHEN IN DRAW MODE  THE CURSOR KEY     ARROWS ARE YOUR ";
600 PRINT"PEN. ON ENTERING DRAW   MODE YOU WILL NOTICE THE PC FLASHING OFFAND ON."
610 PRINT"  THIS IS SET AT IT'S DEFAULT OF NO DRAWOR ERASE. TO BEGIN DRAWING, JUST ";
620 PRINT"PRESS  'D'. TO ERASE, PRESS 'E'."
630 PRINT"  AT ANY TIME YOU MAY RETURN TO THE MAINMENU BY PRESSING 'M'.":PRINT:
632 PRINT" * NOTE: WHEN EVER YOU SELECT 'REDRAW   MODE', THE SCREEN WILL RELOAD. THIS";
633 PRINT" WILLINSURE A PEN COLOR MATCH IF ANY C";"OLOR   SETTING HAS BEEN";
634 PRINT" CHANGED. YOU WILL THEN BE READY TO  RE-DRAW.":PRINT:
640 PRINT:PRINTTAB(1)"<PRESS ANY KEY TO RETURN TO MAIN MENU>"
650 GETKEYK$:GOTO50
660 END
670 X=1:Y=1
680 DRAW1,X,Y
690 GETK$:IFK$=""THEN690
700 IFK$=CHR$(157)THENX=X-1
710 IFK$=CHR$(29)THENX=X+1
720 IFK$=CHR$(145)THENY=Y-1
730 IFK$=CHR$(17)THENY=Y+1
740 IFK$="E"THENGOSUB780
750 IFK$="M"THENGRAPHIC0:GOTO50
760 GOTO680
770 IFX>1ORY>1THEN780:ELSEX=1:Y=1
780 DRAW1,X,Y:DRAW0,X,Y
790 GETK$:IFK$=""THEN780
800 IFK$=CHR$(157)THENX=X-1
810 IFK$=CHR$(29)THENX=X+1
820 IFK$=CHR$(145)THENY=Y-1
830 IFK$=CHR$(17)THENY=Y+1
840 IFK$="D"THENGOTO680
850 IFK$="M"THENGRAPHIC0:GOTO50
860 GOTO780
870 PRINT:INPUT" ENTER FILE NAME TO SAVE (16 CHAR. MAX. ";FL$:C$=CHR$(13)
880 KEY1,"*MONITOR"+C$+"S"+C1$+FL$+C1$+",8,2000,3F41"+C$+"X"+C$+"GOTO1000"+C$
890 PRINT:PRINT" PRESS FUNCTION KEY 1 TO SAVE FILE":PRINT:
900 PRINT" PRESS ANY KEY TO ABORT"
910 GETKEYK$:END
920 GRAPHIC0,1:DIRECTORY
930 PRINT" ";R$;"TO REVIEW DIRECTORY PRESS'D'. TO LOAD"O$;"   ";R$;"FILE PRESS 'L'";O$
940 GETK$:IFK$=""THEN940
950 IFK$="D"THENDIRECTORY:GOTO930
960 IFK$="L"THEN980
970 GOTO940
980 INPUT" FILE NAME TO LOAD ";FL$:L=0
990 TRAP1000:IFL=0THENL=1:GRAPHIC1,1:LOAD(FL$),8,1:PRINTDS$
1000 IFDS>0THENGRAPHIC0,1:PRINTDS$:FORI=0TO1500:NEXT:GOTO50:ELSERESUME
1010 IFFL$>""THENNC=1:L=0:GOTO1020:ELSERETURN
1020 TRAP1000:IFL=0THENL=1:GRAPHIC1,1:LOAD(FL$),8,1:PRINTDS$

READY.